巨大データ掲示板

【2677】ＤＥＳＴＩＮＹＡＳＴＲＡＹ include

名前: ぶれーかー
投稿日時: - 2009年03月05日(木) 03時37分 -
設定: 引用なし
パスワード

##このフォルダに格納されているインクルは、特にマルチパックによる複数規格のパック交換に対応しているものです（と言っても違うのは最後の部分ぐらいですが）
##その関係上、ストライカーパック、シルエット、ウィザードの三種すべてに対応しており、かつアウトフレームに対応しているため
##SEED系の作品を複数参戦させていてどのインクルを使ったらいいか分からないという場合は、とりあえずこれを入れておけば大丈夫です

使用 Unit(対象ユニットＩＤ) シルエット換装 :

If Not 使用済みシルエットナンバー > 0 Then
　使用済みシルエットナンバー = 1
EndIf

戦艦換装シルエットナンバー = 1
For i = 0 To CountItem(未装備)
　If i = 0 Then
　　戦艦換装シルエット[0] = キャンセル
　EndIf
　If Info(アイテム,Item(未装備,i),アイテムクラス) = シルエット Then

　　For j = 1 To 使用済みシルエットナンバー
　
　　　If 使用済みシルエット[j] = Item(未装備,i) Then
　　　　このシルエットは使用済み = 1
　　　EndIf
　　Next

　　　If Not このシルエットは使用済み = 1 Then
　　　　戦艦換装シルエット[戦艦換装シルエットナンバー] = Item(未装備,i)
　　　　Incr 戦艦換装シルエットナンバー
　　　EndIf

　EndIf

UnSet このシルエットは使用済み

Next

Ask 戦艦換装シルエット "$(Info(ユニットデータ,対象ユニットＩＤ,愛称))に装備するシルエットを選択してください"

　If 選択 = 0 Then
　　SpecialPower 対象ユニットＩＤ覚醒
　　Cancel
　EndIf

If Info(マップ, X(対象ユニットＩＤ), Y(対象ユニットＩＤ), 地形クラス) = 空 Then
　If Info(アイテム,戦艦換装シルエット[選択],特殊能力所有, 空中移動) = 0 Then
　　Talk
　　換装可能な地形ではありません
　　End
　　Cancel
　EndIf
EndIf

Exit

使用後 Unit(対象ユニットＩＤ) シルエット換装 :

Call 使用済みシルエット処理

Equip 対象ユニットＩＤ戦艦換装シルエット[選択]

UnSet i
UnSet j
UnSet 戦艦換装シルエットナンバー
UnSet 戦艦換装シルエット
SpecialPower 対象ユニットＩＤ覚醒

Exit

使用済みシルエット処理:

For i = 0 To CountItem(対象ユニットＩＤ)

If Info(アイテム,Item(対象ユニットＩＤ,i),アイテムクラス) = シルエット Then
　使用済みシルエット[使用済みシルエットナンバー] = Item(対象ユニットＩＤ,i)
EndIf

Next

Incr 使用済みシルエットナンバー

Return

使用 Unit(対象ユニットＩＤ) ストライカーパック換装 :

If Not 使用済みSPナンバー > 0 Then
　使用済みSPナンバー = 1
EndIf

#↑戦艦からの換装を使用するとき用の処理

If Info(マップ, X(相手ユニットＩＤ), Y(相手ユニットＩＤ), 地形クラス) = 空 Then
　If Info(アイテム,Item(対象ユニットＩＤ,1),特殊能力所有, 空中移動) = 0 Then
　　Talk
　　換装可能な地形ではありません
　　End
　　Cancel
　EndIf
EndIf

Exit

使用後 Unit(対象ユニットＩＤ) ストライカーパック換装 :

スカグラ武器数 = Info(ユニットデータ,Unit(対象ユニットＩＤ),武器数)

スカグラ装備中パック = (Item(対象ユニットＩＤ,1))

For i = 1 To Info(アイテム,Item(対象ユニットＩＤ,1),武器数)
　ストライカーパック武器名[i] = Info(アイテム,Item(対象ユニットＩＤ,1),武器, i)
　ストライカーパック武器弾数[i] = Info(ユニット,対象ユニットＩＤ,武器, (i + スカグラ武器数), 弾数)
Next

Call 使用済みストライカーパック処理

Equip 対象ユニットＩＤダミーストライカーパック
Equip 相手ユニットＩＤスカグラ装備中パック
RemoveItem (対象ユニットＩＤ) ダミーストライカーパック

For i = 1 To Info(アイテム,Item(相手ユニットＩＤ,1),武器数)
　SetBullet 相手ユニットＩＤストライカーパック武器名[i] ストライカーパック武器弾数[i]
Next

UnSet スカグラ武器数
UnSet スカグラ装備中パック
UnSet ストライカーパック武器名
UnSet ストライカーパック武器弾数

RecoverEN 相手ユニットＩＤ 100

Exit

##以下戦艦側から換装するとき用

使用 Unit(対象ユニットＩＤ) ストライカーパック換装(Ｓ) :

If Not 使用済みSPナンバー > 0 Then
　使用済みSPナンバー = 1
EndIf

戦艦換装SPナンバー = 1
For i = 0 To CountItem(未装備)
　If i = 0 Then
　戦艦換装ストライカーパック[0] = キャンセル
　EndIf
　If Info(アイテム,Item(未装備,i),アイテムクラス) = ストライカーパック Then

　　For j = 1 To 使用済みSPナンバー
　
　　　If 使用済みストライカーパック[j] = Item(未装備,i) Then
　　　　このＳＰは使用済み = 1
　　　EndIf
　　Next

　　　If Not このＳＰは使用済み = 1 Then
　　　　戦艦換装ストライカーパック[戦艦換装SPナンバー] = Item(未装備,i)
　　　　Incr 戦艦換装SPナンバー
　　　EndIf

　EndIf

UnSet このＳＰは使用済み

Next

Ask 戦艦換装ストライカーパック "$(Info(ユニットデータ,対象ユニットＩＤ,愛称))に装備するストライカーパックを選択してください"

　If 選択 = 0 Then
　　SpecialPower 対象ユニットＩＤ覚醒
　　Cancel
　EndIf

If Info(マップ, X(相手ユニットＩＤ), Y(相手ユニットＩＤ), 地形クラス) = 空 Then
　If Info(アイテム,戦艦換装ストライカーパック[選択],特殊能力所有, 空中移動) = 0 Then
　　Talk
　　換装可能な地形ではありません
　　End
　　SpecialPower 対象ユニットＩＤ覚醒
　　Cancel
　EndIf
EndIf

Exit

使用後 Unit(対象ユニットＩＤ) ストライカーパック換装(Ｓ) :

Call 使用済みストライカーパック処理

Equip 対象ユニットＩＤダミーストライカーパック
Equip 相手ユニットＩＤ戦艦換装ストライカーパック[選択]
RemoveItem (対象ユニットＩＤ) ダミーストライカーパック

UnSet i
UnSet j
UnSet 戦艦換装SPナンバー
UnSet 戦艦換装ストライカーパック
RecoverEN 相手ユニットＩＤ 100
Exit

使用済みストライカーパック処理:

For i = 0 To CountItem(相手ユニットＩＤ)

If Info(アイテム,Item(相手ユニットＩＤ,i),アイテムクラス) = ストライカーパック Then
　使用済みストライカーパック[使用済みSPナンバー] = Item(相手ユニットＩＤ,i)
EndIf

Next

Incr 使用済みSPナンバー

Return

##以下アウトフレーム専用処理

*使用後アストレイアウトフレームシルエット換装 :
*使用後アストレイアウトフレームＤシルエット換装 :

Equip 対象ユニットＩＤダミーストライカーパック
RemoveItem 対象ユニットＩＤダミーストライカーパック
Equip 対象ユニットＩＤダミーウィザード
RemoveItem 対象ユニットＩＤダミーウィザード
Equip 対象ユニットＩＤダミーアストレイ換装パーツ
RemoveItem 対象ユニットＩＤダミーアストレイ換装パーツ

Exit

*使用後 Unit(対象ユニットＩＤ) ストライカーパック換装 :
*使用後 Unit(対象ユニットＩＤ) ストライカーパック換装(Ｓ) :

If Unit(相手ユニットＩＤ) = アストレイアウトフレーム or アストレイアウトフレームＤ then
　Equip 相手ユニットＩＤダミーシルエット
　RemoveItem 相手ユニットＩＤダミーシルエット
　Equip 相手ユニットＩＤダミーウィザード
　RemoveItem 相手ユニットＩＤダミーウィザード
　Equip 対象ユニットＩＤダミーアストレイ換装パーツ
　RemoveItem 対象ユニットＩＤダミーアストレイ換装パーツ
EndIf

Exit

901 hits