巨大データ掲示板

【3231】Re(1):ガオガイガー改訂・提案議題

名前: 有翼蛇
投稿日時: - 2009年08月03日(月) 00時33分 -
設定: 引用なし
パスワード

どうも、初めまして（かな？）有翼蛇です。
ベターマンは殆ど知りませんので、ガオガイガーだけ。

>◆議題４：ジェイアークの仕様変更

D案でいいんじゃないでしょうか。次善としてはC案かなと思います。

>◆議題８：ジェネシックとソール１１遊星主

等身大と違ってロボ基準だと光属性はレアですし、残しておいていいのではないでしょうか。
それこそ、さとをさんの意見のようにゾンダーにも光弱点残す形で。
（それに対する補填は必要ないように思います。先にも言いましたがレアですから、味方が持ってたらラッキーくらいで）

他に関しては賛成です。

で、実はここからが本題なのですが……等身大の方で使うようにアニメをちまちま自作していたら
「これヘルアンドヘブンに使えなくね？」ってのができたので、僭越ながら提供させて頂きます。
イメージに合わないようなら却下していただいて全然かまいませんので、ご一考ください。

#animation.txt
ヘルアンドヘブン(準備), 左右粒子集中赤 - ヘル！黄色 - アンドヘブン！！融合緑 - ゲム・ギル・ガン・ゴー・グフォ……！！

#include.eve
#_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/_/
戦闘アニメ_左右粒子集中準備:
戦闘アニメ_左右粒子集中攻撃:
戦闘アニメ_左右粒子集中発動:
戦闘アニメ_左右粒子集中使用:
#引数１色１
#引数２効果音１
#引数３台詞１
#引数４色２
#引数５効果音２
#引数６台詞２
#引数７保持 or 融合
#引数８色３
#引数９効果音３
#引数１０台詞３
#引数１１　ユニットID
## 引数1～6までは順番変更不可。引数７に融合を指示した場合引数8～10も変更不可
## 順番変更不可な引数に"-"を指定した場合、デフォルトで表示されます。

Local i C_X C_Y SIZE B_C Mes
Local UID = _GetName(対象ユニットＩＤ,_GetIDFromArgs())

B_C[1] = _GetName("(Pink)",_G_BC_FA(Args(1)))
B_C[2] = _GetName("(Pink)",_G_BC_FA(Args(4)))
B_C[3] = _GetName("(Pink)",_G_BC_FA(Args(8)))

_UnSetBattleAnimeValue

_CenteringCheck UID
Set C_X (_Get_WX(UID))
Set C_Y (_Get_WY(UID) + 16)

## 右手～

If Args(3) <> "-" Then

Set Mes Args(3)
AutoTalk 対象パイロット
1;$(Mes)
Suspend

Else
　Set Mes ""
EndIf

Wait Start
_SelectSound "Charge.wav" Args(2)

For i = 1 To 5
　Set SIZE ((9 - i) * (9 - i))
　Switch i
　Case 4 5
　　_PaintCutin_ZSL ("Common\EFFECT_Particle" & B_C[1] & "01.bmp") 反転なし (C_X - (SIZE \ 2)) (C_Y - (SIZE \ 2)) SIZE SIZE
　Case 2 3
　　_PaintCutin_ZSL ("Common\EFFECT_Particle" & B_C[1] & "02.bmp") 反転なし (C_X - (SIZE \ 2)) (C_Y - (SIZE \ 2)) SIZE SIZE
　Case 1
　　_PaintCutin_ZSL ("Common\EFFECT_Particle" & B_C[1] & "03.bmp") 反転なし (C_X - (SIZE \ 2)) (C_Y - (SIZE \ 2)) SIZE SIZE
　EndSw

　Wait Until (i * 0.6)
Next

PaintPicture ("Common\EFFECT_LargeElectric" & B_C[1] & "01.bmp") (C_X - 8) (C_Y - 8) 16 16 透過 _ColorTime(1)
Refresh

## 左手～

If Args(6) <> "-" Then
　Mes = (Mes & Args(6))
EndIf

If Mes <> "" Then

AutoTalk 対象パイロット
1;$(Mes)
Suspend

EndIf

Wait Start
_SelectSound "Charge.wav" Args(5)

For i = 1 To 5
　Set SIZE ((9 - i) * (9 - i))
　Switch i
　Case 4 5
　　_PaintCutin_ZSL ("Common\EFFECT_Particle" & B_C[2] & "01.bmp") 反転なし (C_X + 32 - (SIZE \ 2)) (C_Y - (SIZE \ 2)) SIZE SIZE
　Case 2 3
　　_PaintCutin_ZSL ("Common\EFFECT_Particle" & B_C[2] & "02.bmp") 反転なし (C_X + 32 - (SIZE \ 2)) (C_Y - (SIZE \ 2)) SIZE SIZE
　Case 1
　　_PaintCutin_ZSL ("Common\EFFECT_Particle" & B_C[2] & "03.bmp") 反転なし (C_X + 32 - (SIZE \ 2)) (C_Y - (SIZE \ 2)) SIZE SIZE
　EndSw
　PaintPicture ("Common\EFFECT_LargeElectric" & B_C[1] & "01.bmp") (C_X - 8) (C_Y - 8) 16 16 透過 _ColorTime(1)
　Refresh

　Wait Until (i * 0.6)
Next

PaintPicture ("Common\EFFECT_LargeElectric" & B_C[2] & "01.bmp") (C_X + 24) (C_Y - 8) 16 16 透過 _ColorTime(1)
Refresh

Wait Until 5

## 両方～

If Args(7) = "保持" Then
　Return "Keep"
ElseIf Args(7) = "融合" Then

　If Args(10) <> "-" Then

AutoTalk 対象パイロット
1;$(Mes).$(Args(10))
Suspend

　EndIf

　Wait Start

　For i = 0 To 4
　　ClearPicture
　　PaintPicture ("Common\EFFECT_LargeElectric" & B_C[1] & "01.bmp") (C_X - 8 + (i * 3)) (C_Y - 8) 16 16 透過 _ColorTime(1)
　　PaintPicture ("Common\EFFECT_LargeElectric" & B_C[2] & "01.bmp") (C_X + 24 - (i * 3)) (C_Y - 8) 16 16 透過 _ColorTime(1)
　　Refresh
　　Wait Until (i * 0.5)
　Next

　_SelectSound "Charge.wav" Args(9)

　PaintPicture ("Common\EFFECT_LargeElectric" & B_C[3] & "01.bmp") (C_X + 4) (C_Y - 12) 24 24 透過 _ColorTime(1)
　Refresh
　Return "Keep"
Else
　ClearPicture
EndIf

Wait Until 2.5

Return

837 hits